首页 » 未分类 » 正文

重新“封装”VirtualBox命令行管理工具

发布者:站点默认
2011/04/17 浏览数(1,977) 分类:未分类 重新“封装”VirtualBox命令行管理工具已关闭评论

说明:

由于VirtualBox的命令行工具VBoxManage.exe文件名和参数太复杂,使用很不方便,所以upall制作了一个Windows的bat批处理文件来代替VBoxManage.exe。

用法:

将下面的代码保存为“vbox.bat”文件,放到windows目录或system32目录中。然后执行以下命令即可:

vbox start xp   #启动或唤醒名为“xp”的虚拟机
vbox sleep 2k3 #休眠名为“2k3”的虚拟机
vbox off cent   #关闭名为“cent”的虚拟机
vbox list          #列出当前已经安装的虚拟机
vbox vd d:\VMDisk\xp.vdi d:\VMDisk\xpNew.vdi #克隆硬盘,仅复制是不能给新虚拟机用的哦

复制虚拟机可以看这里

代码:

@echo off
:::::::::::::::::::::::::::::::::::::::
:: 说明:管理VirtualBox虚拟机        ::
:: 作者:upall,/ ::
:: 日期:21:33 2011年4月17日 星期日  ::
:::::::::::::::::::::::::::::::::::::::
setlocal
::configureStart
set vbox="%VBOX_INSTALL_PATH%VBoxManage.exe"
set vboxGui="%VBOX_INSTALL_PATH%VirtualBox.exe"

::check configureStart
if "%VBOX_INSTALL_PATH%"=="" set msg=错误:找不到VirtualBox安装位置,您可能还没有安装VirtualBox。&&goto error
if not exist %vbox% set msg=错误:找不到“VBoxManage.exe”。&&goto error
if not exist %vboxGui% set msg=错误:找不到“VBoxManage.exe”。&&goto error

::menu
if "%1"=="" goto vboxGui
if /i "%1"=="gui" goto vboxGui
if /i "%1"=="list" goto list
if /i "%1"=="sleep" goto sleep
if /i "%1"=="resume" goto resume
if /i "%1"=="off" goto poweroff
if /i "%1"=="start" goto startvm
if /i "%1"=="vd" goto clonehd
if /i "%1"=="?" goto help
%vbox% %*
goto end

:vboxGui
start "" %vboxGui%
goto end

:clonehd
%vbox% clonehd %2 %3
goto end

:list
set p=vms
if not "%2"=="" set p=%2
%vbox% list %p%
goto end

:sleep
%vbox% controlvm %2 savestate
goto end

:resume
%vbox% controlvm %2 resume
goto end

:poweroff
%vbox% controlvm %2 poweroff
goto end

:startvm
%vbox% startvm %2
goto end

:error
echo.
echo  %msg%
echo.
goto end

:help
echo  Usage: vbox [start^|sleep^|off^|list^|gui^|resume^|vd^] [name]

:end
endlocal

<完>

点击返回顶部
  1. 留言
  2. 联系方式